Excel: Unentbehrliche Tricks für Ihre Geburtstagsliste

Geburtstagslisten sind beliebte Excel-Objekte. Nur gibt es ein paar Probleme zu umschiffen, die einem erst begegnen, wenn man tatsächlich mit einer solchen Liste arbeitet. Manche betreffen die Sortierung, manche betreffen die Tatsache, dass Geburtstage fürs aktuelle Jahr auch schon wieder vorbei sein können.

«Geburtstag» ist nicht «Alter»: Meistens haben Sie die Geburtsdaten inkl. Jahrgang in Ihrer Liste. Wenn Sie diese Liste schlicht per Klick aufs Sortieren-Icon nach diesen Daten sortieren, dann haben Sie nicht nach Datum, sondern nach Alter sortiert. Die Zeilen erscheinen nicht in der Reihenfolge der Geburtstage, sondern die älteste Person zuoberst, die jüngste zuunterst. Das ist aber meist nicht der Zweck einer Geburstagsliste.

Es gäbe hierfür die Möglichkeit, mit einer Hilfsspalte zu arbeiten, die Monat und Tag aus dem Datum ausliest. Wenn man nach dieser sortiert, stimmt die Reihenfolge der Geburtstage wieder, siehe «Liste nach Geburtstag sortieren, nicht nach Alter». Aber wir haben da eine noch bessere Idee, denn: Wenn schon eine Hilfsspalte, warum dann nicht gleich eine so richtig nützliche?

Wann sind die nächsten Geburtstage? Ermitteln Sie, wann die nächsten Geburtstage auf Ihrer Liste stattfinden – und zwar inkl. Wochentag. Hierfür brauchen wir eine etwas längere Formel. In Spalten A und B haben wir die Namen und Vornamen, in Spalte C haben wir die Geburtsdaten. In Spalte D wollen wir jetzt mit folgender Formel wissen, wann jede Person den nächsten Geburtstag hat. Fügen Sie diese Formel in D2 ein und ziehen Sie diese herunter:

=WENN(DATUM(JAHR(HEUTE());MONAT(C2);TAG(C2))<HEUTE();DATUM(JAHR(HEUTE())+1;MONAT(C2);TAG(C2));DATUM(JAHR(HEUTE());MONAT(C2);TAG(C2)))

Lassen Sie sich nicht irritieren, falls zunächst nur Zahlen wie «43707» erscheinen. Das beheben wir gleich.

Was macht diese Formel? Die oben gezeigte WENN-Formel besteht wie immer aus drei Teilen, sinngemäss: «=WENN(das zutrifft;dann mach dies;sonst mach jenes)». Der erste Teil DATUM(JAHR(HEUTE());MONAT(C2);TAG(C2))<HEUTE() prüft, ob eine Person dieses Jahr schon Geburtstag hatte. Der zweite Teil DATUM(JAHR(HEUTE())+1;MONAT(C2);TAG(C2)) wird verwendet, wenn die erwähnte Prüfung zutrifft; denn in diesem Fall wird nicht das diesjährige (bereits vergangene) Geburtsdatum genommen, sondern jenes vom nächsten Jahr (hierfür das «+1»). Der dritte ist der «sonst»-Teil DATUM(JAHR(HEUTE());MONAT(C2);TAG(C2))), der in allen anderen Fällen zum Zuge kommt.

Zunächst erscheinen nur Zahlen (z.B. 43707). Markieren Sie die Spalte, klicken Sie mit rechts drauf und wählen Sie Zellen formatieren. Sie könnten natürlich unter Kategorie zu Datum greifen und dort eins der Formate auswählen. Aber eleganter wäre doch ein Format, das auch den kurzen Wochentag anzeigt. Wählen Sie darum bei der Kategorie Benutzerdefiniert und tippen Sie bei Typ manuell dieses Format ein: TTT TT.MM.JJJJ. Klicken Sie auf OK.

Ab sofort sortieren Sie die Liste nicht mehr nach dem Geburtsdatum, sondern nach der Spalte Nächster Geburtstag. Und schon stimmt die Reihenfolge wieder.

Lesen Sie auf der nächsten Seite: Wie alt wird die Person? Wer hat einen «Runden»?

Wie alt wird die Person beim nächsten Geburtstag? Die Geburtstagslisten-Optimierung ist noch längst nicht abgeschlossen. Sie möchten doch sicher ohne eigene Rechnerei wissen, wie alt denn die Leute in Ihrer Liste beim nächsten Geburtstag werden. Diese Formel ist nun ein Klacks. Wir hätten die Zahlen für «Wird so alt» gerne in Spalte E. Dort in E2 tuts folgende Formel: =JAHR(D2)-JAHR(C2). Ziehen Sie diese in die restlichen Zellen der Spalte E herunter. Schon sehen Sie, wie alt die Personen bei ihren nächsten Geburtstagen werden.

Runde Geburtstage hervorheben: Damit Sie bei runden Geburtstagen die etwas grösseren Geschenke rechtzeitig beschaffen können, soll Excel die runden Geburtstage hervorheben. Markieren Sie die Zellen mit dem Alter, welche die Personen beim nächsten Geburtstag erreichen werden (hier: «WirdSoAlt»). Gehen Sie im Reiter Start via Bedingte Formatierung zu Neue Regel. Wählen Sie Formel zur Ermittlung der zu formatierenden Zellen verwenden.

Nur die Zehner-Geburtstage: Es gibt eine einfache Formel, die jene hervorhebt, die normale runde Geburtstage 10, 20, 30, 40 bis 110 haben:

=REST($E2;10)=0

Oder sollen es Fünfer-Geburtstage sein? Geht auch:

=REST($E2;5)=0

Ein 35. oder 55. Geburtstag ist für die wenigsten eine grosse Sache. Interessant wird es mit den Fünfer-Schritten normalerweise erst, sobald die Leute etwa das Pensionsalter erreicht haben. Wer es also auf die Spitze treiben will, greift bei der Bedingten Formatierung zu dieser Formel:

=ODER(UND($E2<59;REST($E2;10)=0);UND($E2>59;REST($E2;5)=0))

Damit heben Sie bei unter 59-Jährigen bloss die ganz runden Geburtstage (Zehnerschritte) hervor und bei über 59-Jährigen auch noch die Fünfer-Schritte.

Zusatztipp: Wollen Sie in einer Zusatzspalte den Text «ein Runder» ausgeben, wenn es sich um ein durch 10 teilbares Wiegenfest handelt, und «ein Halb-Runder», falls es durch fünf teilbar ist, können Sie diese Formel verwenden:

=WENN(REST($E2;10)=0;"ein Runder";WENN(REST($E2;5)=0;"ein Halb-Runder";""))

Fehlt noch eine wichtige Formel oder bedingte Formatierung für eine Geburtstagsliste? Schreiben Sie es in die Kommentare.